XPlor/app/app.pro

QT                      += core widgets gui multimedia network

RC_ICONS                 = app.ico

SUBDIRS                 += app

CONFIG                  += c++17

# Load API token from .env file at build time
ENV_FILE = $$PWD/../.env
exists($$ENV_FILE) {
    ENV_CONTENTS = $$cat($$ENV_FILE, lines)
    for(line, ENV_CONTENTS) {
        # Parse GITEA_ACCESS_TOKEN=value
        contains(line, "GITEA_ACCESS_TOKEN=.*") {
            TOKEN = $$replace(line, "GITEA_ACCESS_TOKEN=", "")
            DEFINES += GITEA_ACCESS_TOKEN=\\\"$$TOKEN\\\"
        }
    }
}

SOURCES                 += $$files($$PWD/*.cpp)
HEADERS                 += $$files($$PWD/*.h)
FORMS                   += $$files($$PWD/*.ui)

RESOURCES               += ../data/Data.qrc

LIBS                    += \
                        -L$$PWD/../third_party/devil_sdk/lib/ -lDevIL -lILU -lILUT \
                        -L$$PWD/../third_party/zlib/lib/ -lzlib \
                        -L$$PWD/../third_party/xbox_sdk/lib -lxcompress64 \
                        -L$$OUT_PWD/../libs/ -lcore \
                        -L$$OUT_PWD/../libs/ -lcompression \
                        -L$$OUT_PWD/../libs/ -ldsl \
                        -L$$OUT_PWD/../libs/ -lencryption

INCLUDEPATH             += \
                        $$PWD/../third_party/devil_sdk/include/ \
                        $$PWD/../third_party/zlib/include \
                        $$PWD/../third_party/xbox_sdk/include \
                        $$PWD/../libs/core \
                        $$PWD/../libs/compression \
                        $$PWD/../libs/dsl \
                        $$PWD/../libs/encryption

DEPENDPATH              += \
                        $$PWD/../third_party/devil_sdk/include/ \
                        $$PWD/../third_party/zlib/include \
                        $$PWD/../third_party/xbox_sdk/include \
                        $$PWD/../libs/core \
                        $$PWD/../libs/compression \
                        $$PWD/../libs/dsl \
                        $$PWD/../libs/encryption

CONFIG(debug, debug|release) {
defs_install.path    = $$OUT_PWD/debug/definitions
scripts_install.path = $$OUT_PWD/debug/scripts
} CONFIG(release, debug|release) {
defs_install.path    = $$OUT_PWD/release/definitions
scripts_install.path = $$OUT_PWD/release/scripts
}

defs_install.files     = $$PWD/../definitions/*
scripts_install.files  = $$PWD/../scripts/*
INSTALLS              += defs_install scripts_install