TEMPLATE = app
CONFIG += no_main

# Enable the testlib module
QT += testlib core-private

# Define a test-specific flag
DEFINES += QT_TESTS

TARGET = tests

SOURCES += $$files($$PWD/*.cpp, true)
HEADERS += $$files($$PWD/*.h, true)

# Prevent tests from being built in release mode (optional)
# CONFIG(debug, debug|release) {
#     message("Including test files in Debug mode")
# } else {
#     SOURCES -= autotest_cod5.cpp
# }

LIBS += \
    -L$$OUT_PWD/../libs/ -lcore -lencryption -lcompression -lfastfile -lzonefile -lassets \
    -L$$PWD/../third_party/xbox_sdk/lib -lxcompress64

INCLUDEPATH += \
    $$PWD/../third_party/xbox_sdk/include \
    $$PWD/../libs/core \
    $$PWD/../libs/encryption \
    $$PWD/../libs/compression \
    $$PWD/../libs/fastfile \
    $$PWD/../libs/assets \
    $$PWD/../libs/zonefile

DEPENDPATH += \
    $$PWD/../third_party/xbox_sdk/include \
    $$PWD/../libs/core \
    $$PWD/../libs/encryption \
    $$PWD/../libs/compression \
    $$PWD/../libs/fastfile \
    $$PWD/../libs/assets \
    $$PWD/../libs/zonefile

# Copy DLLs to Debug & Release folder
QMAKE_POST_LINK += xcopy /Y /E /I \"$$PWD/../third_party/xbox_sdk/lib\\*.dll\" \"$$OUT_PWD/debug/\" $$escape_expand(\\n\\t)
QMAKE_POST_LINK += xcopy /Y /E /I \"$$PWD/../third_party/xbox_sdk/lib\\*.dll\" \"$$OUT_PWD/release/\" $$escape_expand(\\n\\t)
